Δομή Επιλογής στο ΑΕΠΠ
Θεωρία, Ασκήσεις και Λυμένα Παραδείγματα

Στην παρακάτω σελίδα θα μπορέσετε να βρείτε όλα όσα χρειάζεται για να είσαστε έτοιμοι στις πανελλήνιες εξετάσεις του μαθήματος της πληροφορικής Γ λυκείου στο κεφάλαιο Δομή Επιλογής. Ένα πολύ σημαντικό κομμάτι ύλης, τιο οποίο μπορεί να πέσει σε οποιοδήποτε Β, Γ και Δ θέμα.

Για να ολοκληρώσετε το διάβασμα σας στο κεφάλαιο της δομής επιλογής πρέπει να είστε έτοιμοι στη Θεωρία, στις μεθοδολογίες, να διαβάσετε τα λυμένα παραδείγματα και να ελέγξετε ότι γνωρίζετε τις ερωτήσεις πολλαπλής επιλογής, Σωστού/Λάθους και αντιστοίχισης. Το κεφάλαιο περιέχει σημαντικά σημεία της ύλης όπως: Απλές χρεώσεις, κλιμακωτές χρεώσεις, Καθαρούς μιθούς φόρους εκπτώσεις πάγια, Επίλεξε, Μενού, απλή, σύνθετη, εμφωλευμένη και πολλαπλή δομή επιλογής.

Τι είναι η δομή επιλογής στην Πληροφορική ΑΕΠΠ

Η δομή επιλογής επιτρέπει στο πρόγραμμα να εκτελεί διαφορετικές εντολές ανάλογα με μια συνθήκη που εξετάζεται τη στιγμή της εκτέλεσης. Αν η συνθήκη είναι αληθής, εκτελείται ένα σύνολο εντολών. Αν είναι ψευδής, εκτελείται ένα άλλο (ή τίποτα). Είναι η δεύτερη βασική δομή του δομημένου προγραμματισμού.

Η δομή επιλογής χωρίζεται στην απλή, τη σύνθετη, την πολλαπλή και την εμφωλευμένη επιλογή. Αν θέλουμε να εξετάσουμε ένα μόνο ενδεχόμενο, χρησιμοποιούμε την απλή δομή (ΑΝ ... ΤΟΤΕ ... ΤΕΛΟΣ_ΑΝ). Για δύο ενδεχόμενα χρησιμοποιούμε τη σύνθετη δομή (ΑΝ ... ΤΟΤΕ ... ΑΛΛΙΩΣ ... ΤΕΛΟΣ_ΑΝ). Για τρία και περισσότερα ενδεχόμενα χρησιμοποιούμε την πολλαπλή δομή. Όταν χρειάζεται να εξετάσουμε υποενδεχόμενα, χρησιμοποιούμε την εμφωλευμένη δομή.

Μορφές της δομής επιλογής και η σύνταξη τους στο ΑΕΠΠ

1. Απλή επιλογή

Οι εντολές εκτελούνται μόνο αν η συνθήκη είναι αληθής.

ΑΝ συνθήκη ΤΟΤΕ
  εντολές
ΤΕΛΟΣ_ΑΝ

2. Σύνθετη επιλογή

Αν η συνθήκη είναι αληθής εκτελούνται οι εντολές_1. Αν είναι ψευδής εκτελούνται οι εντολές_2.

ΑΝ συνθήκη ΤΟΤΕ
  εντολές_1
ΑΛΛΙΩΣ
  εντολές_2
ΤΕΛΟΣ_ΑΝ

3. Πολλαπλή επιλογή

Αν η συνθήκη1 είναι αληθής εκτελούνται οι εντολές_1. Αν όχι, εξετάζεται η συνθήκη2, και ούτω καθεξής. Οι εντολές του ΑΛΛΙΩΣ εκτελούνται όταν καμία συνθήκη δεν είναι αληθής.

ΑΝ συνθήκη1 ΤΟΤΕ
  εντολές_1
ΑΛΛΙΩΣ_ΑΝ συνθήκη2 ΤΟΤΕ
  εντολές_2
ΑΛΛΙΩΣ_ΑΝ ...
  ...
ΑΛΛΙΩΣ
  εντολές_αλλιώς
ΤΕΛΟΣ_ΑΝ

4. Εμφωλευμένη επιλογή

Ένα ΑΝ μέσα σε άλλο ΑΝ, όταν χρειάζεται να εξετάσουμε υποενδεχόμενα.

ΑΝ συνθήκη_1 ΤΟΤΕ
  ΑΝ συνθήκη_2 ΤΟΤΕ
    εντολές
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΑΝ

ΕΠΙΛΕΞΕ (πολλαπλή δομή επιλογής)σύνταξη στο ΑΕΠΠ

Η δομή ΕΠΙΛΕΞΕ είναι δομή πολλαπλής επιλογής με γενική μορφή:

ΕΠΙΛΕΞΕ έκφραση
  ΠΕΡΙΠΤΩΣΗ λίστα_τιμών_1
    εντολές_1
  ΠΕΡΙΠΤΩΣΗ λίστα_τιμών_2
    εντολές_2
  ...
  ΠΕΡΙΠΤΩΣΗ ΑΛΛΙΩΣ
    εντολές_αλλιώς
ΤΕΛΟΣ_ΕΠΙΛΟΓΩΝ

Η έκφραση υπολογίζεται μία φορά και η τιμή της ελέγχεται διαδοχικά σε κάθε ΠΕΡΙΠΤΩΣΗ. Αν δεν ταιριάζει σε καμία, εκτελείται η ΠΕΡΙΠΤΩΣΗ ΑΛΛΙΩΣ, που είναι προαιρετική.

Τι μπορεί να περιέχει μια ΠΕΡΙΠΤΩΣΗ
ΕίδοςΠαράδειγμα
Διακριτές τιμέςΠΕΡΙΠΤΩΣΗ 1, 2, 3
Περιοχή τιμώνΠΕΡΙΠΤΩΣΗ 10..15
Συνθήκη (χωρίς τη μεταβλητή και χωρίς λογικούς τελεστές)ΠΕΡΙΠΤΩΣΗ > 20

ΠΡΟΣΟΧΗ: η ΕΠΙΛΕΞΕ μετατρέπεται μόνο από πολλαπλή δομή επιλογής (ΑΝ ... ΑΛΛΙΩΣ_ΑΝ) και δανείζεται το διάγραμμα ροής του ΑΝ. Η μεταβλητή γράφεται μόνο μία φορά, στην ΕΠΙΛΕΞΕ. Η μορφή «ΠΕΡΙΠΤΩΣΗ Χ > 5» δεν είναι σωστή.

Λυμένο παράδειγμα μετατροπής ΑΝ σε ΕΠΙΛΕΞΕ στο ΑΕΠΠ

Με ΑΝ ... ΑΛΛΙΩΣ_ΑΝ
ΑΝ Βαθμός = 18 ή Βαθμός = 19 ή Βαθμός = 20 ΤΟΤΕ
  ΓΡΑΨΕ 'Άριστα'
ΑΛΛΙΩΣ_ΑΝ Βαθμός >= 10 ΤΟΤΕ
  ΓΡΑΨΕ 'Επιτυχία'
ΑΛΛΙΩΣ
  ΓΡΑΨΕ 'Αποτυχία'
ΤΕΛΟΣ_ΑΝ
Με ΕΠΙΛΕΞΕ (ακέραιος Βαθμός)
ΕΠΙΛΕΞΕ Βαθμός
  ΠΕΡΙΠΤΩΣΗ 18, 19, 20
    ΓΡΑΨΕ 'Άριστα'
  ΠΕΡΙΠΤΩΣΗ 10..17
    ΓΡΑΨΕ 'Επιτυχία'
  ΠΕΡΙΠΤΩΣΗ ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Αποτυχία'
ΤΕΛΟΣ_ΕΠΙΛΟΓΩΝ

Τυπολόγιο δομής επιλογής στο ΑΕΠΠ για πανελλαδικές

Στη ΓΛΩΣΣΑ θα χρειαστεί συχνά να εξετάσουμε αν ένας αριθμός είναι άρτιος, περιττός, ακέραιος, πραγματικός, τριψήφιος ή τετραψήφιος, ποιο είναι το τελευταίο ψηφίο του και αν ο ένας αριθμός διαιρεί τον άλλο. Παρακάτω βρίσκεις τις βασικές συνθήκες.

Τυπολόγιο συνθηκών της δομής επιλογής
ΚατηγορίαΣυνθήκη / Τύπος
ΆρτιοςX MOD 2 = 0
ΠεριττόςX MOD 2 <> 0
ΑκέραιοςX = Α_Μ(X)
ΠραγματικόςX <> Α_Μ(X)
Τριψήφιος (θετικός)X >= 100 ΚΑΙ X <= 999
Τετραψήφιος (θετικός)X >= 1000 ΚΑΙ X <= 9999
Τελευταίο ψηφίοX MOD 10
Το Y διαιρεί το X (X ακέραιο πολλαπλάσιο του Y)X MOD Y = 0

Μεθοδολογίες δομής επιλογής στο ΑΕΠΠ για πανελλαδικές

Πως βρίσκω Μέγιστο και ελάχιστο

Η εύρεση μεγίστου και ελαχίστου είναι από τις βασικότερες μεθοδολογίες του ΑΕΠΠ. Στο παράδειγμα ελέγχουμε ποιος από τρεις αριθμούς είναι ο μεγαλύτερος και ποιος ο μικρότερος.

Εύρεση μεγίστου (MAX)
ΔΙΑΒΑΣΕ a, b, c
max <- a
ΑΝ b > max ΤΟΤΕ
  max <- b
ΤΕΛΟΣ_ΑΝ
ΑΝ c > max ΤΟΤΕ
  max <- c
ΤΕΛΟΣ_ΑΝ
ΓΡΑΨΕ max
Εύρεση ελαχίστου (MIN)
ΔΙΑΒΑΣΕ a, b, c
min <- a
ΑΝ b < min ΤΟΤΕ
  min <- b
ΤΕΛΟΣ_ΑΝ
ΑΝ c < min ΤΟΤΕ
  min <- c
ΤΕΛΟΣ_ΑΝ
ΓΡΑΨΕ min

Θέτουμε αυθαίρετα ως μέγιστο έναν από τους αριθμούς και μετά εξετάζουμε αν κάποιος άλλος είναι μεγαλύτερος. Το ίδιο κάνουμε για το ελάχιστο, εξετάζοντας αν υπάρχει μικρότερος. Εδώ χρησιμοποιούμε διαδοχικές απλές δομές επιλογής (ΑΝ ... ΤΕΛΟΣ_ΑΝ) και όχι ΑΛΛΙΩΣ_ΑΝ, γιατί κάθε αριθμός πρέπει να συγκριθεί με το τρέχον μέγιστο ή ελάχιστο.

Διαφορές Απλής και Κλιμακωτής χρέωσης με λυμένη άσκηση

Ο τρόπος χρέωσης έχει μεγάλη σημασία. Αν δίνεται πίνακας χρέωσης και δεν αναφέρεται πουθενά κλιμακωτή χρέωση, ακολουθούμε την απλή χρέωση. Αν η εκφώνηση ζητά ρητά κλιμακωτή χρέωση, ακολουθούμε μόνο την κλιμακωτή.

Πίνακας χρέωσης του παραδείγματος
Sec€ ανά sec
1 - 1000.5
101 - 2500.7
251 και πάνω0.9
Απλή χρέωση
ΑΝ sec >= 1 ΚΑΙ sec <= 100 ΤΟΤΕ
  Χρ <- sec * 0.5
ΑΛΛΙΩΣ_ΑΝ sec >= 101 ΚΑΙ sec <= 250 ΤΟΤΕ
  Χρ <- sec * 0.7
ΑΛΛΙΩΣ
  Χρ <- sec * 0.9
ΤΕΛΟΣ_ΑΝ
Κλιμακωτή χρέωση
ΑΝ sec >= 1 ΚΑΙ sec <= 100 ΤΟΤΕ
  Χρ <- sec * 0.5
ΑΛΛΙΩΣ_ΑΝ sec >= 101 ΚΑΙ sec <= 250 ΤΟΤΕ
  Χρ <- 100 * 0.5 + (sec - 100) * 0.7
ΑΛΛΙΩΣ
  Χρ <- 100 * 0.5 + 150 * 0.7 + (sec - 250) * 0.9
ΤΕΛΟΣ_ΑΝ

Παράδειγμα για sec = 300: με απλή χρέωση Χρ = 300 * 0.9 = 270 €. Με κλιμακωτή χρέωση Χρ = 100 * 0.5 + 150 * 0.7 + 50 * 0.9 = 50 + 105 + 45 = 200 €.

Πως βρίσκω την Απόλυτη Τιμή - Απόδειξη

Η απόλυτη τιμή είναι πιθανό θέμα συμπλήρωσης κενών στο Θέμα Α. Τη γνωρίζουμε και ως συνάρτηση της ΓΛΩΣΣΑΣ, την Α_Τ(χ).

ΔΙΑΒΑΣΕ α
ΑΝ α < 0 ΤΟΤΕ
  α <- (-1) * α
ΤΕΛΟΣ_ΑΝ
ΓΡΑΨΕ ' | α | = ', α

Συχνά λάθη μαθητών στις παννελλήνιες εξετάσεις πληροφορικής στη δομή επιλογής

Τα συνηθισμένα λάθη έχουν να κάνουν με την υλοποίηση του ΑΝ και με τις βασικές μεθοδολογίες. Η απλή χρέωση είναι εύκολη για τον μαθητή, ενώ η κλιμακωτή είναι δυσκολότερη. Τις περισσότερες φορές το θέμα είναι εμπειρία και πολλές ασκήσεις, σε συνδυασμό με τη γνώση της μεθοδολογίας.

  • Κλιμακωτή χρέωση κάνεις μόνο όταν το λέει ξεκάθαρα η εκφώνηση.
  • Στην πολλαπλή επιλογή ελέγχεις από το πιο ειδικό ή το μεγαλύτερο όριο προς το πιο γενικό, ώστε να μη χάνονται περιπτώσεις.
  • Οι συνθήκες πρέπει να χρησιμοποιούν μεταβλητές που υπάρχουν ήδη στο πρόγραμμα.
  • Οι χαρακτήρες γράφονται πάντα σε εισαγωγικά, π.χ. 'ΝΑΙ'.
  • Αν η μεταβλητή δεν παίρνει τιμή σε κάποιο ενδεχόμενο, αρχικοποίησέ την ή πρόσθεσε ΑΛΛΙΩΣ.
  • Η ΕΠΙΛΕΞΕ γράφει τη μεταβλητή μία φορά, και στις περιπτώσεις μπαίνουν μόνο τιμές, περιοχές ή συνθήκες χωρίς τη μεταβλητή.

Το τυπολόγιο παραπάνω βοηθά στα θέματα Α και Β των πανελλαδικών. Σε συνδυασμό με τη μετατροπή σε ΕΠΙΛΕΞΕ καλύπτεις μεγάλο μέρος των πρώτων και δεύτερων θεμάτων.

Λυμένα παραδείγματα και ασκήσεις ΑΕΠΠ για προετοιμασία πανελλαδικών

Παράδειγμα 1: Απλή, σύνθετη και εμφωλευμένη επιλογή

Εκφώνηση: Να γραφεί πρόγραμμα σε «ΓΛΩΣΣΑ», το οποίο να διαβάζει τρεις πραγματικούς αριθμούς. Αν το άθροισμά τους είναι μεγαλύτερο του 10, να υπολογίζει και να εμφανίζει τον μέσο όρο τους. Διαφορετικά να βρίσκει τον μεγαλύτερο από αυτούς και να τον εμφανίζει με κατάλληλο μήνυμα.

ΠΡΟΓΡΑΜΜΑ Παράδειγμα1
ΜΕΤΑΒΛΗΤΕΣ
  ΠΡΑΓΜΑΤΙΚΕΣ: α, β, γ, ΜΟ, ΜΑΧ
ΑΡΧΗ
  ΔΙΑΒΑΣΕ α, β, γ
  ΑΝ (α + β + γ) > 10 ΤΟΤΕ
    ΜΟ <- (α + β + γ) / 3
    ΓΡΑΨΕ 'ΜΟ=', ΜΟ
  ΑΛΛΙΩΣ                   ! ΣΥΝΘΕΤΗ ΔΟΜΗ
    ΜΑΧ <- α
    ΑΝ β > ΜΑΧ ΤΟΤΕ        ! ΑΠΛΗ ΔΟΜΗ, ΕΜΦΩΛΕΥΜΕΝΗ ΣΤΟ ΑΛΛΙΩΣ
      ΜΑΧ <- β
    ΤΕΛΟΣ_ΑΝ
    ΑΝ γ > ΜΑΧ ΤΟΤΕ        ! ΑΠΛΗ ΔΟΜΗ, ΕΜΦΩΛΕΥΜΕΝΗ ΣΤΟ ΑΛΛΙΩΣ
      ΜΑΧ <- γ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ 'Μεγαλύτερος=', ΜΑΧ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

Εξήγηση: Το εξωτερικό ΑΝ ... ΑΛΛΙΩΣ είναι σύνθετη δομή. Μέσα στον κλάδο ΑΛΛΙΩΣ βρίσκονται δύο απλά ΑΝ, δηλαδή εμφωλευμένες δομές. Για α = 5, β = 4, γ = 3 το άθροισμα είναι 12 και το πρόγραμμα εμφανίζει ΜΟ = 4. Για α = 2, β = 3, γ = 4 το άθροισμα είναι 9 και εμφανίζει Μεγαλύτερος = 4.

Παράδειγμα 2: Μισθοί, επιδόματα, κρατήσεις και τελικός μισθός

Εκφώνηση: Να γραφεί πρόγραμμα σε «ΓΛΩΣΣΑ», το οποίο να υπολογίζει τον μισθό ενός εργαζόμενου που πληρώνεται με την ώρα. Να διαβάζει το όνομά του, τις ώρες εργασίας του για τον μήνα και το ποσό ανά ώρα. Οι κρατήσεις εξαρτώνται από το ύψος του μισθού: αν ο μισθός είναι μέχρι 1000 € έχει 15% κρατήσεις, ενώ διαφορετικά έχει 20%. Αν είναι έγγαμος, έχει επίδομα 50 €. Να υπολογίζει και να τυπώνει τον τελικό μισθό, τις κρατήσεις και το επίδομα.

ΠΡΟΓΡΑΜΜΑ Μισθοί
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: Ον, Απ
  ΠΡΑΓΜΑΤΙΚΕΣ: Ωρες, Ωρομίσθιο, Μισθός, Επίδομα, Κρατήσεις, Τελικός_Μισθός
ΑΡΧΗ
  ΓΡΑΨΕ 'Ονοματεπώνυμο υπαλλήλου'
  ΔΙΑΒΑΣΕ Ον
  ΓΡΑΨΕ 'Ώρες εργασίας'
  ΔΙΑΒΑΣΕ Ωρες
  ΓΡΑΨΕ 'Ωρομίσθιο'
  ΔΙΑΒΑΣΕ Ωρομίσθιο
  Μισθός <- Ωρομίσθιο * Ωρες
  ΓΡΑΨΕ 'Έγγαμος ΝΑΙ ή ΟΧΙ'
  ΔΙΑΒΑΣΕ Απ
  ΑΝ Απ = 'ΝΑΙ' ΤΟΤΕ
    Επίδομα <- 50
  ΑΛΛΙΩΣ
    Επίδομα <- 0
  ΤΕΛΟΣ_ΑΝ
  ΑΝ Μισθός <= 1000 ΤΟΤΕ
    Κρατήσεις <- Μισθός * 15 / 100
  ΑΛΛΙΩΣ
    Κρατήσεις <- Μισθός * 20 / 100
  ΤΕΛΟΣ_ΑΝ
  Τελικός_Μισθός <- Μισθός + Επίδομα - Κρατήσεις
  ΓΡΑΨΕ 'Μισθός=', Μισθός
  ΓΡΑΨΕ 'Κρατήσεις:', Κρατήσεις, ' Επίδομα:', Επίδομα
  ΓΡΑΨΕ 'Τελικός Μισθός=', Τελικός_Μισθός
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
Πίνακας τιμών για δύο εργαζόμενους
ΏρεςΩρομίσθιοΈγγαμοςΜισθόςΚρατήσειςΕπίδομαΤελικός
1608ΝΑΙ1280256 (20%)501074
1009ΟΧΙ900135 (15%)0765

Εξήγηση: Για τον πρώτο εργαζόμενο ο μισθός 1280 € ξεπερνά τα 1000 €, άρα οι κρατήσεις είναι 20% = 256 €. Ο τελικός μισθός είναι 1280 + 50 - 256 = 1074 €. Για τον δεύτερο, 900 € με κρατήσεις 15% = 135 € και χωρίς επίδομα, ο τελικός μισθός είναι 900 - 135 = 765 €.

Παράδειγμα 3: Κλιμακωτή χρέωση νερού

Εκφώνηση: Η ΔΕΥΑΘ χρεώνει το νερό ως εξής: τα πρώτα 5 m³ με 0,50 €/m³, τα επόμενα 10 m³ (6–15) με 0,80 €/m³ και πάνω από 15 m³ με 1,20 €/m³. Να γραφεί πρόγραμμα που διαβάζει τα m³ κατανάλωσης και υπολογίζει το κόστος με κλιμακωτή χρέωση.

ΠΡΟΓΡΑΜΜΑ Α1
ΜΕΤΑΒΛΗΤΕΣ
  ΠΡΑΓΜΑΤΙΚΕΣ: Κατανάλωση, Κόστος
ΑΡΧΗ
  ΔΙΑΒΑΣΕ Κατανάλωση
  ΑΝ Κατανάλωση <= 5 ΤΟΤΕ
    Κόστος <- Κατανάλωση * 0.50
  ΑΛΛΙΩΣ_ΑΝ Κατανάλωση <= 15 ΤΟΤΕ
    Κόστος <- 5 * 0.50 + (Κατανάλωση - 5) * 0.80
  ΑΛΛΙΩΣ
    Κόστος <- 5 * 0.50 + 10 * 0.80 + (Κατανάλωση - 15) * 1.20
  ΤΕΛΟΣ_ΑΝ
  ΓΡΑΨΕ 'Κόστος: ', Κόστος, ' €'
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

Επεξήγηση: Είναι τυπικό πρόβλημα κλιμακωτής χρέωσης. Ελέγχουμε από το μικρότερο προς το μεγαλύτερο όριο. Για κατανάλωση 20 m³: 5 * 0,50 + 10 * 0,80 + 5 * 1,20 = 2,50 + 8,00 + 6,00 = 16,50 €. Κλιμακωτή χρέωση κάνουμε μόνο όταν το ζητά η εκφώνηση.

Παράδειγμα 4: Μέγιστος και ελάχιστος τριών ακεραίων

Εκφώνηση: Να γραφεί πρόγραμμα που διαβάζει τρεις ακεραίους Α, Β, Γ και εμφανίζει τον μεγαλύτερο (MAX) και τον μικρότερο (MIN).

ΠΡΟΓΡΑΜΜΑ Α2
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Α, Β, Γ, MAX, MIN
ΑΡΧΗ
  ΔΙΑΒΑΣΕ Α, Β, Γ
  MAX <- Α
  ΑΝ Β > MAX ΤΟΤΕ
    MAX <- Β
  ΤΕΛΟΣ_ΑΝ
  ΑΝ Γ > MAX ΤΟΤΕ
    MAX <- Γ
  ΤΕΛΟΣ_ΑΝ
  MIN <- Α
  ΑΝ Β < MIN ΤΟΤΕ
    MIN <- Β
  ΤΕΛΟΣ_ΑΝ
  ΑΝ Γ < MIN ΤΟΤΕ
    MIN <- Γ
  ΤΕΛΟΣ_ΑΝ
  ΓΡΑΨΕ 'Μέγιστος: ', MAX
  ΓΡΑΨΕ 'Ελάχιστος: ', MIN
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

Επεξήγηση: Η τεχνική αρχικοποίησης (MAX <- Α, MIN <- Α) και διαδοχικής σύγκρισης είναι η τυπική μέθοδος για MAX/MIN. Επεκτείνεται εύκολα σε Ν αριθμούς με επανάληψη. Αν ζητούν και το όνομα αυτού που έκανε το μέγιστο, κρατάς μία ακόμη μεταβλητή τύπου ΧΑΡΑΚΤΗΡΕΣ, π.χ. ΜΑΧΟΝ, που παίρνει τιμή μαζί με το MAX (ΜΑΧΟΝ <- '1ος αριθμός').

Οι τελεστές στη ΓΛΩΣΣΑ πίνακας για τις πανελλήνιες εξετάσεις Πληροφορικής

Στη ΓΛΩΣΣΑ χρησιμοποιούμε τρία είδη τελεστών: αριθμητικούς, συγκριτικούς και λογικούς. Η προτεραιότητα εκτέλεσης είναι με τη σειρά που γράφτηκαν: πρώτα εκτελούνται όλες οι αριθμητικές πράξεις, μετά όλες οι συγκριτικές και στο τέλος όλες οι λογικές.

Αριθμητικοί τελεστές

Αριθμητικοί τελεστές με σειρά προτεραιότητας
ΠροτεραιότηταΤελεστέςΣημασία
1η^Ύψωση σε δύναμη
2η*, /, DIV, MODΠολλαπλασιασμός, διαίρεση, ακέραιο πηλίκο, ακέραιο υπόλοιπο
3η+, -Πρόσθεση, αφαίρεση

Προσοχή: όταν οι πράξεις έχουν την ίδια προτεραιότητα, εκτελούνται από αριστερά προς τα δεξιά, όπως και στα μαθηματικά. Οι πράξεις DIV και MOD δίνουν πάντα ακέραιο αποτέλεσμα, ενώ η πράξη / δίνει πάντα πραγματικό, ακόμη και όταν το αποτέλεσμα φαίνεται ακέραιο. Για παράδειγμα, 4/2 = 2.0.

Συγκριτικοί τελεστές

Οι συγκριτικοί τελεστές δεν έχουν προτεραιότητα μεταξύ τους. Το αποτέλεσμά τους είναι πάντα λογικό: Αληθής ή Ψευδής.

Συγκριτικοί τελεστές της ΓΛΩΣΣΑ
ΤελεστήςΣημασία
=Ίσο με
<>Διάφορο από
>Μεγαλύτερο από
<Μικρότερο από
>=Μεγαλύτερο ή ίσο
<=Μικρότερο ή ίσο

Λογικοί τελεστές

Οι λογικοί τελεστές εκτελούνται τελευταίοι. Δημιουργούν απλές λογικές εκφράσεις (π.χ. χ > 0) και σύνθετες λογικές εκφράσεις (π.χ. χ > 0 ΚΑΙ ψ < 0). Το αποτέλεσμα είναι πάντα Αληθής ή Ψευδής.

Λογικοί τελεστές με σειρά προτεραιότητας
ΠροτεραιότηταΤελεστήςΑποτέλεσμα
1ηΟΧΙΑντιστρέφει την τιμή της συνθήκης
2ηΚΑΙΑληθής μόνο αν και οι δύο συνθήκες είναι αληθείς
3ηΗΑληθής αν τουλάχιστον μία συνθήκη είναι αληθής

Το διδακτικό πακέτο της ΑΕΠΠ δεν ορίζει ρητά τη σειρά ΚΑΙ και Η. Στις περισσότερες γλώσσες προγραμματισμού το ΚΑΙ προηγείται του Η, και γι' αυτό σε σύνθετες συνθήκες χρησιμοποίησε παρενθέσεις.

Ερωτήσεις Θεωρίας ΑΕΠΠ στη Δομή Επιλογής

Πολλαπλής επιλογής για τις πανελλαδικές εξετάσεις της πληροφορικής

Ερώτηση 1. Ποια από τις παρακάτω χρήσεις της εντολής ΕΠΙΛΕΞΕ είναι σωστή;

  1. ΠΕΡΙΠΤΩΣΗ Χ > 5
  2. ΠΕΡΙΠΤΩΣΗ 1, 2, 3
  3. ΠΕΡΙΠΤΩΣΗ Χ + 1
  4. ΠΕΡΙΠΤΩΣΗ Χ = 1
Δες την απάντηση

Σωστό: β. Η ΠΕΡΙΠΤΩΣΗ δέχεται διακριτές τιμές χωρισμένες με κόμμα, περιοχή τιμών ή συνθήκη χωρίς τη μεταβλητή (π.χ. ΠΕΡΙΠΤΩΣΗ > 5). Οι επιλογές α και δ γράφουν ξανά τη μεταβλητή και η γ είναι έκφραση.

Ερώτηση 2. Ένα πρόγραμμα υπολογίζει έκπτωση: αν η αγορά είναι > 200 € έκπτωση 20%, αν είναι > 100 € έκπτωση 10%, αλλιώς 0%. Ποια δομή είναι η σωστή;

α)
ΑΝ ΑΓΟΡΑ > 200 ΤΟΤΕ
  ΕΚΠΤΩΣΗ <- 0.20
ΑΛΛΙΩΣ
  ΑΝ ΑΓΟΡΑ > 100 ΤΟΤΕ
    ΕΚΠΤΩΣΗ <- 0.10
  ΑΛΛΙΩΣ
    ΕΚΠΤΩΣΗ <- 0
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΑΝ
β)
ΑΝ ΑΓΟΡΑ > 100 ΤΟΤΕ
  ΕΚΠΤΩΣΗ <- 0.10
ΑΛΛΙΩΣ
  ΑΝ ΑΓΟΡΑ > 200 ΤΟΤΕ
    ΕΚΠΤΩΣΗ <- 0.20
  ΑΛΛΙΩΣ
    ΕΚΠΤΩΣΗ <- 0
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΑΝ
γ)
ΑΝ ΑΓΟΡΑ > 100 ΤΟΤΕ
  ΕΚΠΤΩΣΗ <- 0.10
ΤΕΛΟΣ_ΑΝ
ΑΝ ΑΓΟΡΑ > 200 ΤΟΤΕ
  ΕΚΠΤΩΣΗ <- 0.20
ΤΕΛΟΣ_ΑΝ
δ)
ΑΝ ΑΓΟΡΑ > 200 ΤΟΤΕ
  ΕΚΠΤΩΣΗ <- 0.20
ΤΕΛΟΣ_ΑΝ
ΑΝ ΑΓΟΡΑ > 100 ΤΟΤΕ
  ΕΚΠΤΩΣΗ <- 0.10
ΤΕΛΟΣ_ΑΝ
Δες την απάντηση

Σωστό: α. Ελέγχουμε πρώτα το μεγαλύτερο όριο. Στη β ελέγχεται πρώτα το 100, άρα αγορά 250 € παίρνει λάθος έκπτωση 10%. Στη γ, για αγορά ≤ 100 € η ΕΚΠΤΩΣΗ δεν παίρνει ποτέ τιμή. Στη δ, για αγορά 250 € πρώτα γίνεται 0.20 και μετά το δεύτερο ΑΝ την αλλάζει σε 0.10.

Ερώτηση 3. Ποιο τμήμα κώδικα βρίσκει σωστά τον μέγιστο των Α, Β; (υπάρχουν δύο σωστές απαντήσεις)

α)
ΑΝ Α > Β ΤΟΤΕ
  ΜΑΧ <- Α
ΑΛΛΙΩΣ
  ΜΑΧ <- Β
ΤΕΛΟΣ_ΑΝ
β)
ΑΝ Α > Β ΤΟΤΕ
  ΜΑΧ <- Β
ΑΛΛΙΩΣ
  ΜΑΧ <- Α
ΤΕΛΟΣ_ΑΝ
γ)
ΑΝ Α < Β ΤΟΤΕ
  ΜΑΧ <- Α
ΑΛΛΙΩΣ
  ΜΑΧ <- Β
ΤΕΛΟΣ_ΑΝ
δ)
ΜΑΧ <- Α
ΑΝ Β > ΜΑΧ ΤΟΤΕ
  ΜΑΧ <- Β
ΤΕΛΟΣ_ΑΝ
Δες την απάντηση

Σωστό: α και δ. Η α χρησιμοποιεί σύνθετη επιλογή (ΑΝ Α > Β τότε ΜΑΧ = Α). Η δ αρχικοποιεί ΜΑΧ <- Α και ελέγχει αν ο Β είναι μεγαλύτερος, τεχνική χρήσιμη για μέγιστο πολλών αριθμών. Οι β και γ δίνουν τον μικρότερο αντί για τον μεγαλύτερο.

Ερώτηση 4. Ποια τμήματα κώδικα βρίσκουν σωστά τον ελάχιστο των Α, Β, Γ; (υπάρχουν τρεις σωστές απαντήσεις)

α)
ΜΙΝ <- Α
ΑΝ Β < ΜΙΝ ΤΟΤΕ
  ΜΙΝ <- Β
ΤΕΛΟΣ_ΑΝ
ΑΝ Γ < ΜΙΝ ΤΟΤΕ
  ΜΙΝ <- Γ
ΤΕΛΟΣ_ΑΝ
β)
ΜΙΝ <- Α
ΑΝ Β < Α ΤΟΤΕ
  ΜΙΝ <- Β
ΤΕΛΟΣ_ΑΝ
ΑΝ Γ < Β ΤΟΤΕ
  ΜΙΝ <- Γ
ΤΕΛΟΣ_ΑΝ
γ)
ΑΝ Α < Β ΚΑΙ Α < Γ ΤΟΤΕ
  ΜΙΝ <- Α
ΑΛΛΙΩΣ
  ΑΝ Β < Γ ΤΟΤΕ
    ΜΙΝ <- Β
  ΑΛΛΙΩΣ
    ΜΙΝ <- Γ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΑΝ
δ)
ΑΝ Α < Β ΤΟΤΕ
  ΑΝ Α < Γ ΤΟΤΕ
    ΜΙΝ <- Α
  ΑΛΛΙΩΣ
    ΜΙΝ <- Γ
  ΤΕΛΟΣ_ΑΝ
ΑΛΛΙΩΣ
  ΑΝ Β < Γ ΤΟΤΕ
    ΜΙΝ <- Β
  ΑΛΛΙΩΣ
    ΜΙΝ <- Γ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΑΝ
Δες την απάντηση

Σωστό: α, γ και δ. Η α αρχικοποιεί ΜΙΝ <- Α και ελέγχει διαδοχικά κάθε αριθμό. Οι γ και δ χρησιμοποιούν εμφωλευμένη επιλογή. Η β είναι λάθος, γιατί το δεύτερο ΑΝ συγκρίνει το Γ με το Β αντί για το ΜΙΝ. Για Α = 2, Β = 5, Γ = 4 δίνει ΜΙΝ = 4, ενώ ο ελάχιστος είναι το 2.

Σωστό/Λάθος για τις πανελλαδικές εξετάσεις της πληροφορικής

1. Η εντολή ΕΠΙΛΕΞΕ μπορεί να χρησιμοποιηθεί με συνθήκες της μορφής Χ > 5.

Δες την απάντηση

ΛΑΘΟΣ. Η συνθήκη επιτρέπεται, αλλά γράφεται χωρίς τη μεταβλητή (ΠΕΡΙΠΤΩΣΗ > 5). Η μεταβλητή γράφεται μία φορά στην ΕΠΙΛΕΞΕ.

2. Στην απλή επιλογή, αν η συνθήκη είναι ψευδής, το πρόγραμμα τερματίζει.

Δες την απάντηση

ΛΑΘΟΣ. Αν η συνθήκη είναι ψευδής, το πρόγραμμα παρακάμπτει τις εντολές του κλάδου ΤΟΤΕ και συνεχίζει κανονικά.

3. Ο τελεστής ΚΑΙ επιστρέφει ΑΛΗΘΗΣ μόνο όταν και οι δύο συνθήκες είναι αληθείς.

Δες την απάντηση

ΣΩΣΤΟ. Αυτός είναι ο ορισμός του λογικού τελεστή ΚΑΙ (AND).

4. Η εμφωλευμένη επιλογή μπορεί να αντικατασταθεί πάντα από την εντολή ΕΠΙΛΕΞΕ.

Δες την απάντηση

ΛΑΘΟΣ. Η ΕΠΙΛΕΞΕ αντικαθιστά την πολλαπλή δομή επιλογής, όταν ελέγχεται μία έκφραση.

5. Στη σύνθετη επιλογή, όταν η συνθήκη είναι ψευδής εκτελείται ο κλάδος ΑΛΛΙΩΣ.

Δες την απάντηση

ΣΩΣΤΟ. Ο κλάδος ΑΛΛΙΩΣ εκτελείται όταν η συνθήκη είναι ψευδής και ο κλάδος ΤΟΤΕ όταν είναι αληθής.

6. Στις λογικές πράξεις, ο τελεστής ΟΧΙ εκτελείται πριν από τον ΚΑΙ.

Δες την απάντηση

ΣΩΣΤΟ. Η σειρά προτεραιότητας των λογικών τελεστών είναι ΟΧΙ, ΚΑΙ, Η.

7. Η πράξη 4/2 δίνει ακέραιο αποτέλεσμα.

Δες την απάντηση

ΛΑΘΟΣ. Η πράξη / δίνει πάντα πραγματικό αποτέλεσμα: 4/2 = 2.0.

Άσκηση αντιστοίχισης για τις πανελλαδικές εξετάσεις της πληροφορικής

Αντιστοίχισε κάθε εντολή της στήλης Α με τη σωστή λειτουργία της στη στήλη Β. Στη στήλη Β υπάρχουν δύο περιγραφές που περισσεύουν.

Αντιστοίχιση εντολών και λειτουργιών
Στήλη Α: Εντολή / ΔομήΣτήλη Β: Λειτουργία
1. ΑΝ ... ΤΟΤΕ ... ΤΕΛΟΣ_ΑΝα. Εκτελεί εντολές μόνο αν η συνθήκη είναι αληθής, αλλιώς δεν κάνει τίποτα
2. ΑΝ ... ΤΟΤΕ ... ΑΛΛΙΩΣ ... ΤΕΛΟΣ_ΑΝβ. Εκτελείται όταν καμία ΠΕΡΙΠΤΩΣΗ δεν ταιριάζει
3. ΕΠΙΛΕΞΕ ... ΤΕΛΟΣ_ΕΠΙΛΟΓΩΝγ. Ελέγχει την τιμή μιας έκφρασης έναντι πολλών τιμών, περιοχών ή συνθηκών
4. ΠΕΡΙΠΤΩΣΗ ΑΛΛΙΩΣδ. Εκτελεί εντολές_1 αν η συνθήκη είναι αληθής και εντολές_2 αν είναι ψευδής
5. ΑΝ μέσα σε ΑΝε. Εξετάζει υποενδεχόμενα μέσα σε ένα ενδεχόμενο
–στ. Επαναλαμβάνει εντολές όσο ισχύει μια συνθήκη
–ζ. Διαβάζει τιμή από το πληκτρολόγιο
Δες την απάντηση

1 → α, 2 → δ, 3 → γ, 4 → β, 5 → ε. Οι περιγραφές στ (επανάληψη ΟΣΟ) και ζ (ΔΙΑΒΑΣΕ) περισσεύουν.

Συχνές ερωτήσεις για τη δομή επιλογής ΑΕΠΠ

Τι είναι η δομή επιλογής στην ΑΕΠΠ;

Είναι η δομή που επιτρέπει στο πρόγραμμα να εκτελεί διαφορετικές εντολές ανάλογα με μια συνθήκη. Αν η συνθήκη είναι αληθής εκτελείται ένα σύνολο εντολών, αλλιώς εκτελείται ένα άλλο ή τίποτα.

Ποιες είναι οι μορφές της δομής επιλογής;

Η απλή (ΑΝ ... ΤΟΤΕ ... ΤΕΛΟΣ_ΑΝ), η σύνθετη (με ΑΛΛΙΩΣ), η πολλαπλή (με ΑΛΛΙΩΣ_ΑΝ ή με ΕΠΙΛΕΞΕ) και η εμφωλευμένη, όπου ένα ΑΝ βρίσκεται μέσα σε άλλο.

Τι επιτρέπει η εντολή ΕΠΙΛΕΞΕ σε κάθε ΠΕΡΙΠΤΩΣΗ;

Διακριτές τιμές (1, 2, 3), περιοχή τιμών (10..15) ή συνθήκη χωρίς τη μεταβλητή και χωρίς λογικούς τελεστές (π.χ. > 20). Η μεταβλητή γράφεται μία φορά, στην ΕΠΙΛΕΞΕ.

Ποια είναι η προτεραιότητα των λογικών τελεστών;

Πρώτα εκτελείται ο ΟΧΙ, μετά ο ΚΑΙ και τελευταίος ο Η. Σε σύνθετες συνθήκες χρησιμοποίησε παρενθέσεις, γιατί το διδακτικό πακέτο δεν ορίζει ρητά τη σχέση ΚΑΙ και Η.

Πώς βρίσκω τον μέγιστο ή τον ελάχιστο αριθμό;

Θέτεις ως μέγιστο (ή ελάχιστο) έναν από τους αριθμούς και με διαδοχικά απλά ΑΝ ελέγχεις αν κάποιος άλλος είναι μεγαλύτερος (ή μικρότερος), ενημερώνοντας τη μεταβλητή.

Ποια είναι η διαφορά απλής και κλιμακωτής χρέωσης;

Στην απλή χρέωση όλες οι μονάδες χρεώνονται με την τιμή του διαστήματος στο οποίο ανήκει η συνολική κατανάλωση. Στην κλιμακωτή, κάθε διάστημα χρεώνεται με τη δική του τιμή. Κλιμακωτή χρέωση κάνουμε μόνο όταν το ζητά η εκφώνηση.

Go to Top